BBS in a Box 5/BBS in a Box -Volume V (BBS in a Box) (April 1992).iso/Files/Bus/T-Z/Wingz Utilities.cpt/HyperHelp 3.0.SIT/HyperHelp

Wingz Script | 1989-11-15 | 26.2 KB | 642 lines | [WZSC/WNGZ]

WNGZWZSC0110\Q
HyperScript
HyperRef
HyperScript Commands
@HyperScript
E@vents
@Repaint
@Scripts
ToolBo@x
    Co@ntrols
Dialo@gs
@Draw
@Menus
@Objects
@File
Ed@it
Re@port
Se@lect
Windows
@Charts
Fi@elds
Form@at
@Text
Wor@ksheets
    Category@
on mouseup HyperHelp:temp = CTSTRING(1,0)
            if HyperHelp:temp <> HyperHelp:lastcat
                HyperHelp:lastcat = HyperHelp:temp
                call HyperHelp:List(HyperHelp:lastcat)
            end if
           end mouseup
List@
Monaco
bious
COMMAND
PAGE(S)@5
Monaco
Bious
Eon mouseup
            call HyperHelp:Example(CTVALUE(2,0))
           end mouseup
Example@
Monaco
Sort@
call HyperHelp:SortList()
Find Next@
Help@
call HyperHelp:Copy()
call HyperHelp:Search()
    Find Next
call HyperHelp:FindIt()
call HyperHelp:Help()
quit dialog box
             go to window "HyperRef"
           if NAME() = "HyperRef"        { make sure we're closing the correct sheet! }
            close now
           end if
                repaint on
    Category:
    HyperHelp
Geneva
Version 3.0
Geneva
Example
 PLEASE WAIT
HyperRef
HyperScript Commands
Example
Example
 please select a command from the list or choose a new category
Copy to Clipboard
Cancel@
PHyperHelp:ok = 1
           HyperHelp:c = CTVALUE(5,1)
           HyperHelp:x = CTVALUE(5,2)
Command
Example
Find Entry Containing
Cancel@
9HyperHelp:ok = 1
           HyperHelp:searchfor = CTSTRING(4,0)
    Find Next
Example
 PLEASE WAIT
HyperRef
find text "
HyperScript Commands
    Find Next
Example
HyperScript Commands
    Find Next
About HyperHelp
Geneva
XHyperHelp
version 3.0, November 15, 1989
by: Paul T. Christensen and Keith H. Brown
HyperHelp provides an on-line reference to the HyperScript language, supplementing information contained in the Wingz version 1.1 manuals.
A scrollable list of HyperScript commands is located in the center of the HyperHelp window. Use the buttons located above this list to display a different command category. Select an entry from the list to see an example of how it might be used.
Text shown within brackets is optional. For example, "SELECT [MORE] GRAPHICS" represents the commands "SELECT GRAPHICS" and "SELECT MORE GRAPHICS". XYZ
TUnless otherwise noted, page numbers apply to the Wingz 1.1 HyperScript manual.
When the SORT option is checked, the command list is displayed alphabetically. When unchecked, commands are listed in logical groups.
Use the COPY
 button to transfer the current command and/or example to the Clipboard.
The FIND
 button allows the entire command database to be searched for the first item (command, page, or example) that matches a specified set of characters. XYZ
UTo locate the next item using the same search pattern, click on the FIND NEXT button.
cmdwidth
pagewidth
listwidth
lastcat
lastex
searchfor
searchat
found
Hyper
SortList
Examplel
Copyz
Search
FindIt
Help\
{    ------------------------------------------
    HyperHelp
    version 3.0, November 15, 1989
    by: Paul T. Christensen and Keith H. Brown
    ------------------------------------------
    HyperHelp provides a handy on-line reference to the commands in
    the Wingz
 HyperScript language, supplementing the information
    found in the Wingz 1.1 HyperScript manual. When properly installed
    and activated, this script generates a modeless dialog box that can
    remain open along with your sheets and scripts.  You can switch
    between your open scripts and the HyperHelp reference using the
    Window menu.
    HyperScript commands are arranged into 20 different categories that
    can be selected by using the radio buttons at the top of the dialog.
    Normally, each category list is arranged into logical groupings of
    commands. However, you can sort the entire category alphabetically
    using the SORT check box.
    By clicking on an item from the list, you can display an example of
    how the selected command might be used. Because of typographical
    errors, TRY THE EXAMPLE if it seems to contradict the documentation.
    You can copy the command and/or example to the clipboard using the
    COPY
 button.
    The FIND
 button allows you to search for the FIRST entry (starting
    from the top of the HyperRef file) that contains the search string you
    specify. The appropriate category is chosen, and the entry and example
    are highlighted for you. To search for the next occurence of the same
    string, use the FIND NEXT button. Note that FIND
and FIND NEXT will
    match text in the command, page, or example portions of each entry.
IMPORTANT
---------
    Because of the critical nature of dialog control spacing and HyperHelp's
    use of control sorting and naming, this script REQUIRES WINGZ VERSION 1.1.
    DO NOT CHANGE THE FILENAME OF THIS SCRIPT ("HyperHelp")
    OR THE NAME OF ITS REFERENCE FILE ("HyperRef")!
Suggestions for INSTALLATION:
----------------------------
    Copy this file ("HyperHelp") AND its reference worksheet ("HyperRef")
    into the same folder as the Wingz application.
    Create a new script named "Startup" containing the following lines
    and place it in the same folder as the Wingz application.  Or, if
    you already have a Startup file, add these lines to the end of it:
        if file("HyperHelp") and file("HyperRef")
            get script "HyperHelp"
            select menu "Script"
            add menu separator
            add menuitem "HyperScript Help
"  command "@call HyperHelp:Hyper()"
        end if
    To browse the "HyperRef" file, close ALL windows, open HyperRef (it's a Wingz
    worksheet), and choose "Arrange Windows" from the Window menu. Two buttons on
    the sheet will allow you to print the file and show some notes on its operation.
Functions defined by HyperHelp:
-------------------------------
 Hyper()
        main function which opens the reference file and builds the dialog box
 SortList()
        called each time the SORT check box is toggled; turns control sorting
        on or off; re-selects the top list box item
 List(rnge)
        replaces all list box items with the entries of the category RNGE
 Example(row)
        displays the example text for the command on the specified ROW in the
        list box
 Copy()
        generates a dialog box with check boxes for command and example; then
        copies the currently selected command and/or example to the clipboard
        based on the state of the check boxes
 Search()
        displays a dialog prompting the user for a search string; resets search
        pointer to the beginning of the command reference; then calls FindIt()
 FindIt()
        routine searches the command reference from the current search pointer
        using the current search string; if a match is found, the appropriate
        category button is selected, the list is built, and the matching entry
        is highlighted
 fix(str)
        takes all instances of quote marks and replaces them with double-quote
        marks, allowing the returned string to be used in a HyperScript search
        command; this routine was copied from the Wingz 1.1 DG file
 Help()
        displays a dialog with text describing HyperHelp's options
Revision History
----------------
version 3.0, November 15, 1989, Paul T. Christensen
    - added SORT check box to sort the list alphabetically instead of logically
    - modified List() and Example() functions to properly handle examples with SORT on
    - added COPY
 button and Copy() routine to transfer the current command and/or
      example to the Clipboard
    - added FIND
 and FIND NEXT buttons, added Search() and FindIt() routines to
      search the entire HyperRef file for items that match a specified search string
    - added support for FIND mode to the List() routine
    - modified List() to right-justify page references and display "Please Wait" message
    - changed Help() window placement and rewrote the help text
    - now retains settings for category, sort, and search string
    - now checks the worksheet NAME() before closing it to avoid accidentally closing
      a user's window instead of the HyperRef sheet
    - renamed idx() to List(); exmple() to Example()
    - optimized code and converted variables from global to local where possible
    - updated installation instructions, documentation, and worksheet note
    - renamed "HyperScript_Ref" to "HyperRef" to distinguish from previous versions
    - COMPLETELY rebuilt HyperRef: added new commands from Wingz 1.1, re-organized
      and renamed categories, organized items logically within each category;
      corrected all known errors; added category list to the beginning of the file.
    - merged Database category into Worksheet; added HyperScript category and merged
      Functions and Sound entries into it; added File and Edit categories; renamed
      Print to Report, Toolbox to ToolBox, changed Event, Script, Control, Dialog,
      Menu, Object, Window, Chart, Field, and Worksheet to their plural names
version 2.5, September 21, 1989, Paul T. Christensen (never released publicly)
    - updated control spacing and dialog repainting to work with Wingz version 1.1
    - example field now displays help text if no entry is selected in the list box
version 2.4, June 22, 1989, Keith H. Brown
    - added additional controls to HyperScript_Ref for printing and notes
    - changed name of reference sheet from "HyperScript Ref" to "HyperScript_Ref"
      to allow variable to be defined in the sheet script
    - removed an extraneous range name "Foo" from HyperScript_Ref
version 2.3, June 22, 1989, Paul T. Christensen
    - fixed a potentially disastrous bug where clicking on the OK button might
      close a user's worksheet without saving instead of closing "HyperScript Ref"
      Kudos to Steve Schroader for finding this bug-a-boo.
    - corrected page setup, print area, sheet reduction, and font problems in
      "HyperScript Ref"; expanded note description and reorganized some items
version 2.2, June 19, 1989, Paul T. Christensen
    - added title and version number to dialog box
    - changed category names: "Drawing" to "Draw", "Printing" to "Print"
    - added explanatory text block (note) to "HyperScript Ref"
    - verified "HyperScript Ref"; added missing commands; improved organization;
      added missing commands; corrected errors
    - checked and corrected ALL examples by compiling their text!
    - corrected minor error in the installation instructions
version 2.1, June 12, 1989, Keith H. Brown
    - disabled text field in the Help dialog box
version 2.0, June 9, 1989, Paul T. Christensen
    - redesigned dialog: moved OK and Help buttons next to each other; made list
      longer, now uses Monaco 9 plain (holds 56 characters)
    - examples are automatically displayed when a category is selected and when
      an entry is selected from the list box.  If the example entry in the
      reference file contains a single quote, a copy of the command is used
    - minimized dialog repainting by checking to see if the radio button was the
      same as the last button chosen
    - redesigned help box: removed scroll bar, reworded help text, used Geneva 9
    - assigned quick key shortcuts to most items in the dialog box
    - added error handler to trap for "worksheet already open" errors. This is
      required because the "HyperScript Ref" file is not closed if the user
      uses the modeless dialog close box instead of the OK button.
    - "HyperScript Ref" has been extensively rebuilt. Now, commands are listed
      with the parameter names, errors have been corrected, commands have been
      added, and organization has been improved.
    - merged Constructs button with Functions; merged Distribution, Matrix, and
      What_If buttons into the Worksheet category
    - added Object, Repaint, Select, and Text categories/buttons
    - renamed files to "HypHelp" and "HyperScript Ref"
version 1.1, May 29, 1989, Keith H. Brown
    - displays an example when a command is double-clicked
    - repaints list box instead of entire dialog
version 1.0, May 26, 1989, Keith H. Brown
    - initial public release
define cmdwidth,pagewidth,listwidth
define sort,lastcat,lastex,searchfor,searchat,found
define ok,temp,r,c,x
function Hyper()
    cmdwidth = 56        { maximum width of command description in characters }
    pagewidth = 19        { maximum width of page number reference in characters }
    listwidth = cmdwidth + pagewidth + 1    { width of list box = command & space & page }
    if lastcat = "" or lastcat = 0        { if never called before, set first category }
        lastcat = "HyperScript"
    end if
    open "HyperRef"    { Load the reference file if it isn't already open }
    new modeless dialog box "HyperScript Commands" at (-1,-1) (9680,5710)
    { Control #1: "Category" Radio buttons }
    add radio button "@HyperScript","E@vents","@Repaint","@Scripts","ToolBo@x",
        "Co@ntrols","Dialo@gs","@Draw","@Menus","@Objects" at (1650,72) +(7900,1600)
    add radio button items "@File","Ed@it","Re@port","Se@lect","Windows",
        "@Charts","Fi@elds","Form@at","@Text","Wor@ksheets"
    control name "Category@"
    hide control name
    no line border
    select control item lastcat
    script "on mouseup HyperHelp:temp = CTSTRING(1,0)
            if HyperHelp:temp <> HyperHelp:lastcat
                HyperHelp:lastcat = HyperHelp:temp
                call HyperHelp:List(HyperHelp:lastcat)
            end if
           end mouseup"
    { Control #2: "List" box }
    add list box "" at (40,1800) +(9600,2800)
    control name "List@"
    hide control name
    text font "Monaco"
    text size 9
    text style "bious"
    show scroll bar list box
    show control title "COMMAND"&REPEAT(" ",48)&"PAGE(S)@"
    control title text font "Monaco"
    control title text style "Bious"
    control title text size 9
    control title text color BLUE()
    script "on mouseup
            call HyperHelp:Example(CTVALUE(2,0))
           end mouseup"
    { Control #3: "Example" field }
    add field at (80,5350) +(9530,300)
    control name "Example@"
    field left margin 3
    text font "Monaco" text size 9
    disable control
    { Control #4: Sort check box }
    add check box "Sort@" at (100,1400) +(900,300)
    no line border
    script "call HyperHelp:SortList()"
    if sort
        check box 1
        select control "List"
        control sorting on
    end if
    { Controls 5,6,7,8,9: Copy
, Find
, Find Next, Help, and OK buttons }
    add push button "Copy
@","Find
@","Find Next@","Help@","OK@"
        at (100,4750) +(9400,420)
    select control "Copy
    script "call HyperHelp:Copy()"
    select control "Find
    script "call HyperHelp:Search()"
    select control "Find Next"
    script "call HyperHelp:FindIt()"
    if searchfor = "" or searchfor = 0        { grey FIND NEXT if no valid search string }
        grey control
        searchfor = ""
    end if
    select control "Help"
    script "call HyperHelp:Help()"
    select control "OK"
    dialog default push button
    script "quit dialog box
             go to window ""HyperRef""
           if NAME() = ""HyperRef""        { make sure we're closing the correct sheet! }
            close now
           end if
                repaint on"
    add text "Category:" at (100,100) +(1400,300)
    no line border
    add text "HyperHelp" at (100,600) +(1000,260)
    text font "Geneva"  text size 9  text color BLUE()
    no line border
    add text "Version 3.0" at (100,850) +(1300,260)
    text font "Geneva"  text size 9  text color BLUE()
    no line border
    call List(lastcat)
    use dialog box
end function    { Hyper() }
function SortList()
    select control "List"
    if not sort
        sort = 1
        control sorting on                { sort the list alphabetically }
        top list box item 1                { display and select first item in list }
        select control item 1
        call Example(-1)
    else
        sort = 0
        control sorting off
        call List(CTSTRING(1,0))            { rebuild list box items with original order }
    end if
end function     { SortList() }
function List(rnge)
define c,rows,cols,i,starting,ending,cmd,page,builditem,founditem
    if not found                        { display status message while building list }
        select control "Example"
        align center
        text color RED()
        field text "
 PLEASE WAIT
    end if
    repaint off                        { we don't want to watch the list box being built }
    invalidate on                        { remember the areas that will need repainting }
    go to window "HyperRef"
    select range rnge
    r = ROWOF(SELECTION(1))
    c = COLOF(SELECTION(1))
    rows = ROWS(SELECTION(1)) - 1
    cols = COLS(SELECTION(1)) - 1
    go to window "HyperScript Commands"
    select control "List"
    starting = r
    ending = (r + rows)
    for i = starting to ending
        page = INDIRECT(MAKECELL(c+1,i))
        if ISNUMBER(page)            { convert page numbers to strings for LENGTH function }
            page = STR(page)
        end if
        cmd = LEFT(INDIRECT(MAKECELL(c,i)),cmdwidth)        { Truncate commands that are too long }
        page = LEFT(page,pagewidth)                    { Truncate long page references }
        builditem = cmd & REPEAT(" ",listwidth - (LENGTH(cmd)+LENGTH(page))) & page & "   "
            & i - starting + 1            { append real index to worksheet in case we SORT }
        if not found or (found and rnge <> lastcat)    { Don't redo list on FIND in same category }
            if i = r                    { first entry replaces all list items }
                list box items builditem
            else                        { add items to the list }
                add list box items builditem
            end if
        end if
        if i = searchat and found        { make note of the list box entry on FIND operation }
            founditem = builditem
        end if
    end for
    if found                            { display and select entry that was FOUND }
        top list box item founditem
        select control item founditem
    else
        select control item 1            {
otherwise, select the first list item }
    end if
    lastex = -1                        { force drawing of first example item }
    select control "Example"
    align left
    text color BLACK()
    if found
        found = 0
        call Example(CTVALUE(2,0))        { display example for FOUND entry }
    else
        call Example(1)                {
otherwise, display example for first item }
    end if
end function    { List(rnge) }
function Example(row)
define content
    if row <> lastex    { Change example entry ONLY if it's changed since last filled }
        lastex = row
        if sort        { For SORT mode, grab the real index from the end of the list entry }
            row = VALUE(MID(CTSTRING(2,0),listwidth+3,3))
        end if
        select control "Example"
        if row <> 0
            content = INDIRECT(MAKECELL(3,r+(row-1)))
            if content = "'"  field text INDIRECT(MAKECELL(1,r+(row-1)))
            else field text content
            end if
        else
            field text "
 please select a command from the list or choose a new category
        end if
    end if
    invalidate off                    { now we can draw all the changes that have happened }
end function    { Example(row) }
function Copy()
define cmd,ex
    if not c and not x
        c = 1
    end if
    new modal dialog box at (-1,-1) (4900,1500)
    add text "Copy to Clipboard
" at (100,50) (3000,450)
    no line border
    add text "line" at (100,450) (3500,470)
    add push button "OK@","Cancel@" at (4000,50) (4500,1350)
    dialog cancel push button
    select control 3  dialog default push button
    script "HyperHelp:ok = 1
           HyperHelp:c = CTVALUE(5,1)
           HyperHelp:x = CTVALUE(5,2)"
    add check box "Command","Example" at (300,650) (2500,1400)
    no line border
    if c  check box 1  end if
    if x  check box 2  end if
    ok = 0
    use dialog box
    if ok and (c or x)
        cmd = TRIM(LEFT(CTSTRING(2,0),cmdwidth))
        ex = TRIM(CTSTRING(3,0))
        new worksheet "" location (100inch,100inch) (100inch,100inch)
        if c
            put cmd into A1
            if x
                put ex into A2
            end if
        elseif x
            put ex into A1
        end if
        select active cells
        copy
        close now
    end if
end function     { Copy() }
function Search()
    new modal dialog box at (-1,-1) (5300,1350)
    add text "Find Entry Containing
" at (100,250) (3500,650)
    no line border
    add push button "OK@","Cancel@" at (4400,50) (4900,1350)
    dialog cancel push button
    select control 2  dialog default push button
    script "HyperHelp:ok = 1
           HyperHelp:searchfor = CTSTRING(4,0)"
    add field at (100,850) (3700,1250)
    field word wrap off
    field text searchfor
    maximum field length 200
    ok = 0
    use dialog box
    if ok
        if searchfor = ""
            select control "Find Next"
            grey control
        else
            searchat = 23                { start our search at the beginning of the entries }
            call FindIt()                { perform the actual search }
        end if
    end if
end function    { Search() }
function    FindIt()
define loop,cat
    select control "Example"                { display status message while searching HyperRef }
    align center
    text color RED()
    field text "
 PLEASE WAIT
    go to window "HyperRef"
    select range MAKECELL(3,searchat)        { start search from example field to avoid "double hits" }
    run "find text """&fix(searchfor)&""""
    if NRSELECTIONS() = 0 or ROWOF(SELECTION(1)) < INDIRECT(MAKECELL(2,2))
       or ROWOF(SELECTION(1)) > INDIRECT(MAKECELL(3,21))        { Failed Search }
        select range lastcat
        go to window "HyperScript Commands"
        select control "Find Next"
        grey control
        lastex = -1                    { force drawing of first example item }
        select control "Example"            { re-display example text }
        align left
        text color BLACK()
        call Example(CTVALUE(2,0))
    else                                { search was successful
 currently on the found row }
        searchat = ROWOF(SELECTION(1))
        loop = 2                        { identify the category using start of HyperRef }
        while searchat > INDIRECT(MAKECELL(3,loop))
            loop = loop + 1
        end while
        cat = INDIRECT(MAKECELL(1,loop))
        go to window "HyperScript Commands"
        select control 1
        select control item cat
        found = 1
        call List(cat)
        lastcat = cat
        select control "Find Next"
        ungrey control
    end if
end function    { FindIt() }
function fix(s0)
define i,c,l,s1
    s1=""
    l=length(s0)
    for i=1 to l
        c=mid(s0,i-1,1)
        s1=s1&c
        if c=""""            { Replace quotes with two double quotes for HyperScript search }
            s1=s1&""""
        end if
    end for
    return s1
end function    { fix(so) }
function Help()
    new modal dialog box at (-1,-1) (7300,4120)
    add text "About HyperHelp
" at (100,200) +(3000,400)
    no line border
    add push button "OK@" at (6000,100) +(1200,450)
    dialog default push button
    add field at (50,750) +(7200,3320)
    field single font
    text font "Geneva"
    text size "9"
    field justification flush
    field right margin 5 points
    field left margin 5 points
    field top margin 5 points
    field bottom margin 3 points
    show scroll bar field
    field text "HyperHelp"&char(13)&"version 3.0, November 15, 1989"&char(13)&
        "by: Paul T. Christensen and Keith H. Brown"&char(13)&char(13)&"XYZ"
    replace field text "XYZ" with "HyperHelp provides an on-line reference to the HyperScript "&
        "language, supplementing information contained in the Wingz version 1.1 manuals."&
        char(13)&char(13)&"XYZ" options "Aw"
    replace field text "XYZ" with "A scrollable list of HyperScript commands is located in the "&
        "center of the HyperHelp window. Use the buttons located above this list to display a "&
        "different command category. Select an entry from the list to see an example of "&
        "how it might be used."&char(13)&char(13)&"XYZ" options "Aw"
    replace field text "XYZ" with "Text shown within brackets is optional. For example, "&
        """SELECT [MORE] GRAPHICS"" represents the commands ""SELECT GRAPHICS"" and ""SELECT "&
        "MORE GRAPHICS"". "&"XYZ" options "Aw"
    replace field text "XYZ" with "Unless otherwise noted, page numbers apply to the Wingz 1.1 "&
        "HyperScript manual."&char(13)&char(13)&"XYZ" options "Aw"
    replace field text "XYZ" with "When the SORT option is checked, the command list is displayed "&
        "alphabetically. When unchecked, commands are listed in logical groups."&char(13)&char(13)&
        "XYZ" options "Aw"
    replace field text "XYZ" with "Use the COPY
 button to transfer the current command and/or "&
        "example to the Clipboard."&char(13)&char(13)&
        "The FIND
 button allows the entire command database to be searched for the first item "&
        "(command, page, or example) that matches a specified set of characters. "&"XYZ" options "Aw"
    replace field text "XYZ" with "To locate the next item using the same search pattern, click "&
        "on the FIND NEXT button." options "Aw"
    select field text from 0 to 0
    lock field text
    use dialog box
end function    { Help() }
on error
    if LERROR() <> 1025            { ignore "Worksheet already open" errors }
        message SERROR()
    end if
end error